home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Spanish Scene 1
/
SpanishScene1.iso
/
spanish pack n°1 by llfb
/
revistas
/
trashcan
/
trashcan01-1.dms
/
trashcan01-1.adf
/
Fuentes
/
SourceDistortions.lzx
/
Distortions.s
Wrap
Text File
|
1981-10-08
|
19KB
|
1,178 lines
bltcon0 equ $dff040
bltcon1 equ $dff042
bltafwm equ $dff044
bltalwm equ $dff046
bltcpth equ $dff048
bltbpth equ $dff04c
bltapth equ $dff050
bltdpth equ $dff054
bltsize equ $dff058
bltcmod equ $dff060
bltbmod equ $dff062
bltamod equ $dff064
bltdmod equ $dff066
bltcdat equ $dff070
bltbdat equ $dff072
bltadat equ $dff074
cop1 equ $dff080
cop2 equ $dff084
copjmp1 equ $dff088
copjmp2 equ $dff08a
SECTION Rauling,CODE
InitSys
bsr.s OSout
bsr.w Start
bsr.w OSin
rts
dc.b "$VER: Distortions Intro Version 3.1 25-Jul-95",0
cnop 0,4
OSout
movea.l 4.w,a6 ; System Base
lea GfxLib,a1
moveq #0,d0
jsr -552(a6) ; OpenLibrary
move.l d0,GfxBase ; Save Graphics_lib base
move.l d0,a6
move.l 38(a6),OldCopper ; gb_CopInit Sys Copper
move.l 34(a6),OldView ; gb_ActiView Sys View
jsr -456(a6) ; Own Blitter
lea 0.w,a1 ;LoadView Null
jsr -222(a6) ;LoadView
jsr -270(a6) ;WaitTOF
jsr -270(a6)
movea.l 4.w,a6 ; System Base
jsr -132(a6) ; Forbid
jsr -150(a6) ; SuperState
move.l d0,SysStack ; System stack
btst.b #0,$129(a6) ; are we at least 68010? ($129=AttnFlags+1)
beq.s .68000 ; nope.
movec.l vbr,d0
move.l d0,VectorBase ; Get Real VBR
btst.b #2,$129(a6)
beq.s .68000
move.l #$ff,detect_30
.68000 move $dff01c,IntEnaR ; Initialize custom chips
move $dff01e,IntReqR ; Save old valours first
move $dff002,DmaConR
move $dff010,AdkConR
move #%0111111111111111,$dff09a ; INTENA
move #%1100000000100000,$dff09a * Enable desired IRQs
.Spr move.l $dff004,D0 ; Wait RASTER to
and.l #$0001FF00,D0 ; disable SPRITES
bne.s .Spr
move #%0111111111111111,$dff096 ; DMACONW
move #%1000001111000000,$dff096 * Enable desired DMAs
move $dff07c,d0 ;Ponerlo en/antes/despues de Copper?
cmp.b #$f8,d0
bne.s .NotAGA ; Not AGA
move #0,$dff1fc * Fix AGA Res (Ponerlo en Copper?)
.NotAGA move.l VectorBase,a0
move.l $6c(a0),Int3Save ; Save level 3 vector
move.l #INTER,$6c(a0) ; Set OUR! own interrupt
rts
cnop 0,4
OSin
move.l VectorBase,a0
move.l Int3Save,$6c(a0) ; Reset Interrupts
move IntEnaR,d7 ; Reset custom chips
bset #$f,d7
move d7,$dff09a ; Reset Interrupts
move IntReqR,d7
bset #$f,d7
move d7,$dff09c ; Reset interrupt request
move DmaConR,d7
bset #$f,d7
move d7,$dff096 ; Reset DMAConw
move AdkConR,d7
bset #$f,d7
move d7,$dff09e ; Reset ADK
move.l GfxBase,a6
movea.l OldView,a1
jsr -222(a6) ;LoadView
move.l OldCopper,$dff080 ; Reset System Copper
jsr -462(a6) ; DisOwn Blitter
movea.l 4.w,a6 ; System Base
move.l GfxBase,a1 ; Close Graphics_lib
jsr -414(a6) ; CloseLibrary
jsr -138(a6) ; Permit
move.l SysStack,d0 ; Systemstack
jsr -156(a6) ; UserState
moveq.l #0,D0
rts
MUSICA=0
***************** INTERRUPCION
cnop 0,4
INTER movem.l A0-A6/D0-D7,-(sp)
addq.l #1,timer
IFEQ MUSICA
cmp.l #$ff,detect_30
bne.s _ca_ok
movec.l cacr,d0
bclr.l #30,d0
movec.l d0,cacr
_ca_ok
bsr mt_music
cmp.l #$ff,detect_30
bne.s _si_ok
movec.l cacr,d0
bset.l #30,d0
movec.l d0,cacr
_si_ok
ENDC
move #$20,$dff09c
movem.l (sp)+,A0-A6/D0-D7
rte
***************** PROGRAMA
cnop 0,4
Start
lea bpl0,a0
move.l #small,d0
move d0,6(a0)
swap d0
move d0,2(a0)
swap d0
add.l #2400,d0
move d0,14(a0)
swap d0
move d0,10(a0)
swap d0
add.l #2400,d0
move d0,22(a0)
swap d0
move d0,18(a0)
swap d0
add.l #2400,d0
move d0,30(a0)
swap d0
move d0,26(a0)
lea bpl1,a0
move.l #calav,d0
move d0,6(a0)
swap d0
move d0,2(a0)
swap d0
add.l #10240,d0
move d0,14(a0)
swap d0
move d0,10(a0)
swap d0
add.l #10240,d0
move d0,22(a0)
swap d0
move d0,18(a0)
swap d0
move.l #plano1,d0
move d0,30(a0)
swap d0
move d0,26(a0)
move.l #plano1+120,d0
move d0,38(a0)
swap d0
move d0,34(a0)
lea btbpl,a0
move.l #bgtnc,d0
move d0,6(a0)
swap d0
move d0,2(a0)
swap d0
add.l #10240,d0
move d0,14(a0)
swap d0
move d0,10(a0)
swap d0
add.l #10240,d0
move d0,22(a0)
swap d0
move d0,18(a0)
swap d0
add.l #10240,d0
move d0,30(a0)
swap d0
move d0,26(a0)
swap d0
add.l #10240,d0
move d0,38(a0)
swap d0
move d0,34(a0)
lea disbpl,a0
move.l #titulo,d0
move d0,6(a0)
swap d0
move d0,2(a0)
swap d0
add.l #10240,d0
move d0,14(a0)
swap d0
move d0,10(a0)
swap d0
add.l #10240,d0
move d0,22(a0)
swap d0
move d0,18(a0)
swap d0
add.l #10240,d0
move d0,30(a0)
swap d0
move d0,26(a0)
lea mc0,a0
move.l #small,d0
move d0,6(a0)
swap d0
move d0,2(a0)
swap d0
add.l #2400,d0
move d0,14(a0)
swap d0
move d0,10(a0)
swap d0
add.l #2400,d0
move d0,22(a0)
swap d0
move d0,18(a0)
swap d0
add.l #2400,d0
move d0,30(a0)
swap d0
move d0,26(a0)
lea mc1,a0
move.l #mc_11,d0
move d0,6(a0)
swap d0
move d0,2(a0)
swap d0
add.l #$a00,d0
move d0,14(a0)
swap d0
move d0,10(a0)
lea a64.bpl,a0
move.l #a64k,d0
move d0,6(a0)
swap d0
move d0,2(a0)
swap d0
add.l #10240,d0
move d0,14(a0)
swap d0
move d0,10(a0)
move.l #texto,puntsig
IFEQ MUSICA
lea mt_dat1,a0
bsr mt_init
ENDC
bsr btshow
bsr aishow
move.l #distcop,cop1
bsr fadein
move.l #639,d2
buc2 bsr.s frame
dbra d2,buc2
bsr fadeout
buc3 bsr.s infinite_bobs
buc4
bsr.s frame
move.l #fincop,cop1
lmb bsr.s frame
bsr scrv
btst #6,$bfe001
bne.s lmb
fin
bsr wablit
bsr.s frame
IFEQ MUSICA
bsr mt_end
ENDC
rts
cnop 0,4
frame
cmp.b #254,$dff006
bne.s frame
frame1
cmp.b #255,$dff006
bne.s frame1
rts
b_inf MACRO
lea mc1pal,a0
move.w #0,2(a0)
move.w #0,6(a0)
move.w #0,10(a0)
move.w #0,14(a0)
bsr inf_borr
bsr frame
lea mc1pal,a0
move.w #0,2(a0)
move.w #$555,6(a0)
move.w #$aaa,10(a0)
move.w #$fff,14(a0)
ENDM
infinite_bobs
bsr.s frame
move.l #macop,cop1
bsr.s frame
move.l #0,inf_temp
move.l #0,inf_fr_scr
move.l #0,inf_fr_bob
move.l #1,inf_path
bra inf6
inf1
bsr inf_ch
cmp.l #1023,inf_temp
bgt.s inf2
move.l #0,d6
move.l #0,d7
move.w (a5),d6
move.w 2(a5),d7
move.l a6,a0
lea bobgfx,a1
lea bobmask,a2
clr.l d0
clr.l d1
move.l d6,d0
move.l d7,d1
bsr blit
move.l a6,a0
add.l #$2800,a0
lea bobgfx+64,a1
lea bobmask,a2
move.l d6,d0
move.l d7,d1
bsr blit
add.l #4,a5
inf2
addq.l #1,inf_fr_scr
cmp.l #8,inf_fr_scr
bne.s inf3
clr.l inf_fr_scr
inf3
addq.l #1,inf_fr_bob
cmp.l #10,inf_fr_bob
bne.s inf4
clr.l inf_fr_bob
inf4
add.l #1,inf_temp
cmp.l #1174,inf_temp
bgt inf5
bra inf1
inf5
move.l #0,inf_temp
b_inf
add.l #1,inf_path
cmp.l #4,inf_path
beq.s inf_fin
inf6
cmp.l #1,inf_path
beq.s _ifp_1
cmp.l #2,inf_path
beq.s _ifp_2
cmp.l #3,inf_path
beq.s _ifp_3
cmp.l #4,inf_path
beq.s _ifp_4
_ifp_1
lea inf_p_1,a5
bra inf1
_ifp_2
lea inf_p_2,a5
bra inf1
_ifp_3
lea inf_p_3,a5
bra inf1
_ifp_4
lea inf_p_4,a5
bra inf1
cnop 0,4
inf_fin
bsr.s inf_ch
add.b #2,mcypos
cmp.b #$fd,mcypos
blt.s inf_fin
rts
inf_borr
lea mc_11,a6
move.l #$1400*8,d0
subq.l #1,d0
inf_b_2
move.l #0,(a6)+
dbra d0,inf_b_2
rts
inf_ch
clr.l d0
move.l inf_fr_scr,d0
mulu.w #$5000,d0
move.l #0,a6
lea mc_11,a6
add.l d0,a6
bsr frame
lea mc1,a0
move.l a6,d0
move d0,6(a0)
swap d0
move d0,2(a0)
swap d0
add.l #$2800,d0
move d0,14(a0)
swap d0
move d0,10(a0)
rts
; Imprimir bob
; a0-->bitplane a1-->bob a2-->mascara
; d0-->xpos d1-->ypos
cnop 0,4
blit
bsr.s wablit
move.l a2,bltapth
move.l a1,bltbpth
clr.l d2
clr.l d3
move.l d0,d2
and.l #$f,d2
swap d2
ror.l #4,d2
move.l d2,d3
or.l #$fca,d2
swap d2
or.l d2,d3
move.l d3,bltcon0
and.l #$fff0,d0
ror.l #3,d0
mulu.w #40,d1
add.l d0,d1
add.l d1,a0
move.l a0,bltcpth
move.l a0,bltdpth
move.w #36,bltcmod
move.w #36,bltdmod
move.l #0,bltbmod
move.l #$ffffffff,bltafwm
move.w #$402,bltsize
rts
cnop 0,4
wablit
btst.b #6,$dff002
bne.s wablit
btst.b #6,$dff002
bne.s wablit
rts
; borrado de memoria con blitter
; a0 puntero
; d0 n° bytes (par)
cnop 0,4
clrbpl
clr.l (a0)+
dbra d0,clrbpl
rts
cnop 0,4
scrv
btst.b #2,$bfe017
beq.s scrv_fin
addq.b #1,scroltmp
cmp.b #2,scroltmp
beq.s scrv1
scrv_fin
rts
scrv1 clr.b scroltmp
bsr wablit
move.l #$0ff00000,bltcon0 ; modos de copia
move.l #$ffffffff,bltafwm ; mascara fuente A
move.l #plano1,bltdpth ; destino
move.l #plano1+40,bltapth ; fuente A
move.l #0,bltamod ; borra modulos A y D
move.w #$3494,bltsize
bsr wablit
addq.b #1,letratmp ; Incrementa tiempo para linea nueva
cmp.b #10,letratmp ; Imprime
beq.s prline ; si es 10
rts
cnop 0,4
prline
clr.l letratmp
move.l #plano1+(194*40),a2
move.l puntsig,a3
tst.b (a3)
bne.s prlne2
movea.l #texto,a3
prlne2 bsr.s ptext
move.l a3,puntsig
rts
** Printtext sub **
** a2 --> Scan Inicio **
** a3 --> Direccion texto **
cnop 0,4
ptext
clr.l d0
move.b (a3)+,d0
cmp.b #10,d0
bne.s ptext2
rts
ptext2 move.l a2,a0
subq.b #1,d0
bsr.s pchar
addq.l #1,a2
bra.s ptext
** Print Subrutine **
** d0 --> Caracter **
** a0 --> Scan de inicio **
cnop 0,4
pchar
asl.l #3,d0
move.l #font,a1
add.l d0,a1
moveq.l #7,d1
pchar1 move.b (a1)+,(a0)
lea 40(a0),a0
dbra d1,pchar1
rts
cnop 0,4
numcols equ 15
numbucs equ 63
fadein
move.l #$dff180,a4
moveq.l #numcols,d0
fadein1
clr.w (a4)+
dbra d0,fadein1
lea tmp,a2
lea target,a3
move.l #$dff180,a4
move.l a2,a0
move.l a3,a1
moveq.l #numbucs,d0
fadein2
move.b (a1),d1
sub.b #16,d1
move.b d1,(a0)+
clr.b (a1)+
dbra d0,fadein2
moveq.l #15,d0
fadein3
move.l a2,a0
move.l a3,a1
moveq.l #numbucs,d1
fadein4
move.b (a0),d2
addq.b #1,d2
move.b d2,(a0)+
bge.s fadein5
clr.b d2
fadein5
move.b d2,(a1)+
dbra d1,fadein4
move.l a3,a0
move.l a4,a1
moveq.l #numcols,d6
fadein6
clr.l d1
clr.l d2
clr.l d3
move.b (a0)+,d1
move.b (a0)+,d2
move.b (a0)+,d3
addq.l #1,a0
rol.b #4,d2
rol.w #8,d1
or.w d1,d2
or.w d2,d3
move.w d3,(a1)+
dbra d6,fadein6
bsr frame
dbra d0,fadein3
rts
fadeout
lea tmp,a2
lea target,a3
move.l #$dff180,a4
move.l a2,a0
move.l a3,a1
moveq.l #numbucs,d0
fadeout1
move.b (a1)+,(a0)+
dbra d0,fadeout1
moveq.l #15,d0
fadeout2
move.l a2,a0
move.l a3,a1
moveq.l #numbucs,d1
fadeout3
move.b (a0),d2
subq.b #1,d2
move.b d2,(a0)+
bge.s fadeout4
clr.b d2
fadeout4
move.b d2,(a1)+
dbra d1,fadeout3
move.l a3,a0
move.l a4,a1
moveq.l #numcols,d6
fadeout5
clr.l d1
clr.l d2
clr.l d3
move.b (a0)+,d1
move.b (a0)+,d2
move.b (a0)+,d3
addq.l #1,a0
rol.b #4,d2
rol.w #8,d1
or.w d1,d2
or.w d2,d3
move.w d3,(a1)+
dbra d6,fadeout5
bsr frame
bsr frame
dbra d0,fadeout2
rts
timess equ 80
timehl equ 40
cnop 0,4
btshow
bsr frame
move.l #btcop,cop1
clr.l d0
move.b #timess,d0
bt1 bsr frame
dbra d0,bt1
move.l #15,d0
lea btde1,a0
lea btor1,a1
bt1_1
move.l (a1)+,(a0)+
dbra d0,bt1_1
clr.l d0
move.b #timess,d0
bt2 bsr frame
dbra d0,bt2
lea btl1,a0
move.w #$567,2(a0)
move.w #$acd,6(a0)
move.w #$add,10(a0)
move.w #$bdd,14(a0)
clr.l d0
move.b #timess,d0
bt3 bsr frame
dbra d0,bt3
move.l #31,d0
lea btl2,a0
lea btor2,a1
bt3_1
move.l (a1)+,(a0)+
dbra d0,bt3_1
clr.l d0
move.b #timess,d0
bt4 bsr frame
dbra d0,bt4
lea btl3,a0
move.w #$567,2(a0)
move.w #$acd,6(a0)
move.w #$add,10(a0)
move.w #$bdd,14(a0)
clr.l d0
move.w #timess*4,d0
bt_fin bsr frame
dbra d0,bt_fin
rts
cnop 0,4
aishow
bsr frame
move.l #a64cop,cop1
lea a64.0,a0
move.w #$000,2(a0)
move.w #$b78,6(a0)
move.w #$745,10(a0)
move.w #$e9a,14(a0)
clr.l d0
move.b #timess,d0
ai1 bsr frame
dbra d0,ai1
lea a64.1,a0
move.w #$000,2(a0)
move.w #$b78,6(a0)
move.w #$745,10(a0)
move.w #$e9a,14(a0)
clr.l d0
move.b #timess,d0
ai2 bsr frame
dbra d0,ai2
lea a64.2,a0
move.w #$000,2(a0)
move.w #$b78,6(a0)
move.w #$745,10(a0)
move.w #$e9a,14(a0)
clr.l d0
move.b #timess,d0
ai3 bsr frame
dbra d0,ai3
lea a64.3,a0
move.w #$000,2(a0)
move.w #$b78,6(a0)
move.w #$745,10(a0)
move.w #$e9a,14(a0)
clr.l d0
move.b #timess,d0
ai4 bsr frame
dbra d0,ai4
lea a64.4,a0
move.w #$000,2(a0)
move.w #$b78,6(a0)
move.w #$745,10(a0)
move.w #$e9a,14(a0)
clr.l d0
move.b #timess,d0
ai5 bsr frame
dbra d0,ai5
lea a64.5,a0
move.w #$000,2(a0)
move.w #$b78,6(a0)
move.w #$745,10(a0)
move.w #$e9a,14(a0)
ai_fin clr.l d0
move.w #timess*3,d0
ai_f_1 bsr frame
dbra d0,ai_f_1
rts
IFEQ MUSICA
include "replay.s"
ENDC
***************** COPPER LIST
SECTION CopperLists,DATA_C
cnop 0,4
fincop
dc.w $08e,$2881,$090,$28C1 ; DIWindow Size YX
dc.w $092,$0038,$094,$00D0 ; DDFetch
dc.w $100,$4200 ; BPLCONtrol0
dc.w $108,$0000,$10a,$0000
bpl0 dc.w $0e0,$0000,$0e2,$0000
dc.w $0e4,$0000,$0e6,$0000
dc.w $0e8,$0000,$0ea,$0000
dc.w $0ec,$0000,$0ee,$0000
dc.w $0180,$0000,$0182,$0FFF
dc.w $0184,$0EEE,$0186,$0DDDf
dc.w $0188,$0CCC,$018A,$0BBB
dc.w $018C,$0AAA,$018E,$0999
dc.w $0190,$0888,$0192,$0777
dc.w $0194,$0666,$0196,$0555
dc.w $0198,$0444,$019A,$0333
dc.w $019C,$0222,$019E,$0111
dc.w $01a0,$0444
dc.w $6401,$fffe
dc.w $100,$0200
dc.w $108,$0000,$10a,$0000
bpl1 dc.w $0e0,$0000,$0e2,$0000
dc.w $0e4,$0000,$0e6,$0000
dc.w $0e8,$0000,$0ea,$0000
dc.w $0ec,$0000,$0ee,$0000
dc.w $0f0,$0000,$0f2,$0000
dc.w $180,$000,$182,$333 ;paleta original
dc.w $184,$555,$186,$777
dc.w $188,$AAA,$18A,$CCC
dc.w $18C,$FFF,$18E,$000
; dc.w $180,$000,$182,$111
; dc.w $184,$333,$186,$555
; dc.w $188,$777,$18a,$999
; dc.w $18C,$bbb,$18e,$000
dc.w $0190,$0000 ; Sombra
dc.w $0192,$0111
dc.w $0194,$0222
dc.w $0196,$0333
dc.w $0198,$0444
dc.w $019a,$0555
dc.w $019c,$0666
dc.w $019e,$0000
dc.w $6501,$fffe
dc.w $100,$5200 ; BPLCONtrol0
cf3 equ $0fff
dc.w $01a2,cf3
dc.w $01a4,cf3
dc.w $01a6,cf3
dc.w $01a8,cf3
dc.w $01aa,cf3
dc.w $01ac,cf3
dc.w $01ae,cf3
dc.w $01b0,cf3 ; 31
dc.w $01b2,cf3
dc.w $01b4,cf3
dc.w $01b6,cf3
dc.w $01b8,cf3
dc.w $01ba,cf3
dc.w $01bc,cf3
dc.w $01be,cf3
dc.w $01c0,cf3
dc.w $6601,$fffe
dc.w $01a0,$888
dc.w $6701,$fffe
dc.w $01a0,$ccc
dc.w $6801,$fffe
dc.w $01a0,$fff
dc.w $ffff,$fffe,$ffff,$fffe
cnop 0,4
distcop
dc.w $08e,$2881,$090,$28C1 ; DIWindow Size YX
dc.w $092,$0038,$094,$00D0 ; DDFetch
dc.w $100,$4200 ; BPLCONtrol0
dc.w $108,$0000,$10a,$0000
disbpl dc.w $0e0,$0000,$0e2,$0000
dc.w $0e4,$0000,$0e6,$0000
dc.w $0e8,$0000,$0ea,$0000
dc.w $0ec,$0000,$0ee,$0000
dc.w $ffff,$fffe,$ffff,$fffe
cnop 0,4
btcop
dc.w $08e,$2881,$090,$28C1 ; DIWindow Size YX
dc.w $092,$0038,$094,$00D0 ; DDFetch
dc.w $100,$5200 ; BPLCONtrol0
dc.w $108,$0000,$10a,$0000
btbpl dc.w $0e0,$0000,$0e2,$0000
dc.w $0e4,$0000,$0e6,$0000
dc.w $0e8,$0000,$0ea,$0000
dc.w $0ec,$0000,$0ee,$0000
dc.w $0f0,$0000,$0f2,$0000
btde1
dc.w $180,$000,$182,$000,$184,$000,$186,$000 ; 0
dc.w $188,$000,$18A,$000,$18C,$000,$18E,$000 ; 4
dc.w $190,$000,$192,$000,$194,$000,$196,$000 ; 8
dc.w $198,$000,$19A,$000,$19C,$000,$19E,$000 ; 12
dc.w $7a01,$fffe
btl1 dc.w $0182,$0000,$19a,$000,$19c,$000,$19e,$000
dc.w $9501,$fffe
btl2 dc.w $180,$000,$182,$000,$184,$000,$186,$000 ; 0
dc.w $188,$000,$18A,$000,$18C,$000,$18E,$000 ; 4
dc.w $190,$000,$192,$000,$194,$000,$196,$000 ; 8
dc.w $198,$000,$19A,$000,$19C,$000,$19E,$000 ; 12
dc.w $1A0,$000,$1A2,$000,$1A4,$000,$1A6,$000 ; 16
dc.w $1A8,$000,$1AA,$000,$1AC,$000,$1AE,$000 ; 20
dc.w $1B0,$000,$1B2,$000,$1B4,$000,$1B6,$000 ; 24
dc.w $1B8,$000,$1BA,$000,$1BC,$000,$1BE,$000 ; 28
dc.w $fe01,$fffe
btl3 dc.w $0182,$0000,$19a,$000,$19c,$000,$19e,$000
dc.w $ffff,$fffe,$ffff,$fffe
cnop 0,4
macop dc.w $08e,$2881,$090,$28C1 ; DIWindow Size YX
dc.w $092,$0038,$094,$00D0 ; DDFetch
dc.w $100,$4200 ; BPLCONtrol0
dc.w $108,$0000,$10a,$0000
mc0 dc.w $0e0,$0000,$0e2,$0000
dc.w $0e4,$0000,$0e6,$0000
dc.w $0e8,$0000,$0ea,$0000
dc.w $0ec,$0000,$0ee,$0000
dc.w $0180,$0000,$0182,$0FFF
dc.w $0184,$0EEE,$0186,$0DDD
dc.w $0188,$0CCC,$018A,$0BBB
dc.w $018C,$0AAA,$018E,$0999
dc.w $0190,$0888,$0192,$0777
dc.w $0194,$0666,$0196,$0555
dc.w $0198,$0444,$019A,$0333
dc.w $019C,$0222,$019E,$0111
mcypos dc.w $6401,$fffe
dc.w $0100,$2200 ; BPLCONtrol0
dc.w $0108,$0000,$010a,$0000
mc1 dc.w $00e0,$0000,$00e2,$0000
dc.w $00e4,$0000,$00e6,$0000
mc1pal dc.w $0180,$0000,$0182,$0555
dc.w $0184,$0aaa,$0186,$0fff
dc.w $ffff,$fffe,$ffff,$fffe
a64cop dc.w $08e,$2881,$090,$28C1 ; DIWindow Size YX
dc.w $092,$0038,$094,$00D0 ; DDFetch
dc.w $0100,$2200 ; BPLCONtrol0
dc.w $0108,$0000,$010a,$0000
a64.bpl dc.w $00e0,$0000,$00e2,$0000
dc.w $00e4,$0000,$00e6,$0000
a64.0 dc.w $0180,$0000,$0182,$0000
dc.w $0184,$0000,$0186,$0000
dc.w $5401,$fffe
a64.1 dc.w $0180,$0000,$0182,$0000
dc.w $0184,$0000,$0186,$0000
dc.w $7201,$fffe
a64.2 dc.w $0180,$0000,$0182,$0000
dc.w $0184,$0000,$0186,$0000
dc.w $9f01,$fffe
a64.3 dc.w $0180,$0000,$0182,$0000
dc.w $0184,$0000,$0186,$0000
dc.w $e501,$fffe
a64.4 dc.w $0180,$0000,$0182,$0000
dc.w $0184,$0000,$0186,$0000
dc.w $fe01,$fffe
a64.5 dc.w $0180,$0000,$0182,$0000
dc.w $0184,$0000,$0186,$0000
dc.w $ffff,$fffe,$ffff,$fffe
SECTION Titulos,DATA_C
cnop 0,4
bgtnc incbin "datas/bg_tnc_32.raw"
cnop 0,4
a64k incbin "datas/a64k.raw"
SECTION Distortions,DATA_C
cnop 0,4
titulo incbin "datas/distortions.raw"
cnop 0,4
small incbin "datas/small.raw"
SECTION Calavera,DATA_C
cnop 0,4
calav incbin "datas/calavera.raw"
dcb.l 920,0
SECTION Bobs,DATA_C
cnop 0,4
bobgfx incbin "datas/bob.raw"
cnop 0,4
bobmask incbin "datas/bob-mask.raw"
IFEQ MUSICA
SECTION Musica_1,DATA_C
cnop 0,4
mt_dat1 incbin "datas/mod.chip"
ENDC
SECTION bitplanes,BSS_C
cnop 0,4
nulo dcb.l 10,0
cnop 0,4
plano1 dcb.l $1400,0
cnop 0,4
mc_11 dcb.l $1400*8,0
************** DATAS
SECTION Variables,DATA
cnop 0,4
GfxLib dc.b "graphics.library",0
cnop 0,4
IntEnaR dc.l 0
IntReqR dc.l 0
DmaConR dc.l 0
AdkConR dc.l 0
SysStack dc.l 0
Int3Save dc.l 0
GfxBase dc.l 0
OldCopper dc.l 0
OldView dc.l 0
VectorBase dc.l 0
timer dc.l 0
scroltmp dc.l 0
letratmp dc.l 0
puntsig dc.l 0
inf_temp dc.l 0
inf_fr_bob dc.l 0
inf_fr_scr dc.l 0
inf_path dc.l 0
detect_30 dc.l 0
cnop 0,4
inf_p_1
incbin "datas/inf-path-1.raw"
inf_p_2
incbin "datas/inf-path-2.raw"
inf_p_3
incbin "datas/inf-path-3.raw"
inf_p_4
incbin "datas/inf-path-4.raw"
cnop 0,4
font dcb.b 32*8,0
incbin "datas/font-mano.raw"
cnop 0,4
texto
incbin "datas/texto-new.asc"
dc.l 0
tmp dc.l 0,0,0,0
dc.l 0,0,0,0
dc.l 0,0,0,0
dc.l 0,0,0,0
target dc.l $00000400
dc.l $0e0e0e00
dc.l $00000000
dc.l $0c0b0900
dc.l $070a0800
dc.l $06060600
dc.l $0a0a0a00
dc.l $04060500
dc.l $01040300
dc.l $06090a00
dc.l $09080500
dc.l $06050200
dc.l $03060700
dc.l $00030400
dc.l $06040700
dc.l $04020500
cnop 0,4
btor1
dc.w $0180,$0000,$0182,$0122,$0184,$0233,$0186,$0344 ; 0
dc.w $0188,$0445,$018A,$0456,$018C,$0467,$018E,$0578
dc.w $0190,$0689,$0192,$069A,$0194,$07AB,$0196,$08BC ; 8
dc.w $0198,$09CC,$019A,$0ACD,$019C,$0ADD,$019E,$0BDD
btor2
dc.w $0180,$0000,$0182,$0122,$0184,$0233,$0186,$0344 ; 0
dc.w $0188,$0445,$018A,$0456,$018C,$0467,$018E,$0578
dc.w $0190,$0689,$0192,$069A,$0194,$07AB,$0196,$08BC ; 8
dc.w $0198,$09CC,$019A,$0ACD,$019C,$0ADD,$019E,$0BDD
dc.w $01A0,$0B84,$01A2,$0C95,$01A4,$0555,$01A6,$0DB8 ; 16
dc.w $01A8,$0989,$01AA,$005A,$01AC,$0DA6,$01AE,$0777
dc.w $01B0,$0CA9,$01B2,$0999,$01B4,$0CCC,$01B6,$05CC ; 24
dc.w $01B8,$00BB,$01BA,$00AC,$01BC,$0000,$01BE,$09DD